GroebnerBasis[{x y -1,x^2y-1},{x,y}, MonomialOrder->DegreeLexicographic]

(* Solving Polynomials in two variables *)
ContourPlot[{x^2 - y^2-3==0,2x^2+ 3y^2- 11==0},{x,-4,4},{y,-4,4}]

GroebnerBasis[{x^2 - y^2-3,2x^2+ 3y^2- 11},{x,y}, MonomialOrder->Lexicographic]

(* Solving Polynomials in three variables *)
f1 = x^2+y^2+z^2-1;
f2=x^2+z^2-y;
f3=x-z;
ContourPlot3D[{f1==0,f2==0,f3==0},{x,-2,2},{y,-2,2},{z,-2,2}]

GroebnerBasis[{f1,f2,f3},{x,y,z}, MonomialOrder->Lexicographic]

(* Parametric curve*)

f1 = t^2 - 1; f2 = t^3 - t;
ParametricPlot[{f1,f2},{t,-1.5,1.5}]

GroebnerBasis[{x-(t^2-1),y-(t^3-t)},{t,x,y},MonomialOrder->Lexicographic]

ContourPlot[(x^2)+(x^3)-(y^2)==0,{x,-2,2},{y,-2,2}]

(* Parametric curve in 3D*)
ParametricPlot3D[{t,t^2,t^3},{t,-1,1},PlotStyle->{Black, Thick}]

GroebnerBasis[{x-t,y-t^2,z-t^3},{t,x,y,z},MonomialOrder->Lexicographic]

Show[{ContourPlot3D[{(y^3)-(z^2)==0,-(y^2)+x z==0,x y-z==0,(x^2)-y==0},{x,-1,1},{y,-1,1},{z,-1,1}],ParametricPlot3D[{t,t^2,t^3},{t,-1,1},PlotStyle->{Black, Thick}]}]

(*Robot Arm *)
GroebnerBasis[{x-(c+c^2-s^2),y-(s+2 c s), c^2+s^2-1},{c,s,x,y},MonomialOrder->Lexicographic]

Curve = ContourPlot[-2 x-3 (x^2)+(x^4)-3 (y^2)+2 (x^2) (y^2)+(y^4)==0,{x,-2,2},{y,-2,2}]

Animate[Show[{Curve,Graphics[{Thick,Line[{{0,0},{Cos[t],Sin[t]} ,{Cos[t],Sin[t]} + {Cos[2t],Sin[2t]}  }]}]}],{t,0,2Pi}]

(*Chaning arm length *)
Manipulate[Show[{ParametricPlot[{Cos[t],Sin[t]} + r{Cos[2t],Sin[2t]}  ,{t,0,2Pi},Axes->None],Graphics[{Thick,Line[{{0,0},{Cos[t],Sin[t]} ,{Cos[t],Sin[t]} + r{Cos[2t],Sin[2t]}  }]}]}],{t,0,2Pi},{r,.5,2}]